https://gist.github.com/tmk/6020478
http://danikgames.com/blog/making-the-caps-lock-key-very-useful-on-windows/
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
; Autohotkey Capslock Remapping Script
; Danik
; More info at http://danikgames.com/blog/?p=714
; danikgames.com
;
; Functionality:
; - Deactivates capslock for normal (accidental) use.
; - Hold Capslock and drag anywhere in a window to move it (not just the title bar).
; - Access the following functions when pressing Capslock:
; Cursor keys - 해피해킹
; Enter - Space
; Home, PgDn, PgUp, End - 해피해킹
; Backspace and Del - N, M - 모름
;
; Insert - \
; Select all - A
; Cut, copy, paste - S, D, F
; Close tab, window - W, E
; Esc - R
; Next, previous tab - Tab, Q
; Undo, redo - , and . 주석처리
;
; To use capslock as you normally would, you can press WinKey + Capslock
; This script is mostly assembled from modified versions of the following awesome scripts:
;
; # Home Row Computing by Gustavo Duarte: http://duartes.org/gustavo/blog/post/home-row-computing for
; Changes:
; - Does not need register remapping of AppsKey using SharpKeys.
; - Uses normal cursor key layout
; - Added more hotkeys for insert, undo, redo etc.
;
; # Get the Linux Alt+Window Drag Functionality in Windows: http://www.howtogeek.com/howto/windows-vista/get-the-linux-altwindow-drag-functionality-in-windows/
; Changes: The only change was using Capslock instead of Alt. This
; also removes problems in certain applications.
#Persistent
SetCapsLockState, AlwaysOff
Capslock & 1:: Send {Blind}{Capslock up}{F1}
Capslock & 2:: Send {Blind}{Capslock up}{F2}
Capslock & 3:: Send {Blind}{Capslock up}{F3}
Capslock & 4:: Send {Blind}{Capslock up}{F4}
Capslock & 5:: Send {Blind}{Capslock up}{F5}
Capslock & 6:: Send {Blind}{Capslock up}{F6}
Capslock & 7:: Send {Blind}{Capslock up}{F7}
Capslock & 8:: Send {Blind}{Capslock up}{F8}
Capslock & 9:: Send {Blind}{Capslock up}{F9}
Capslock & 0:: Send {Blind}{Capslock up}{F10}
Capslock & -:: Send {Blind}{Capslock up}{F11}
Capslock & =:: Send {Blind}{Capslock up}{F12}
; Capslock + jkli (left, down, up, right)
Capslock & SC027 ::Send {Blind}{Left DownTemp}
Capslock & SC027 up::Send {Blind}{Left Up}
Capslock & /::Send {Blind}{Down DownTemp}
Capslock & / up::Send {Blind}{Down Up}
Capslock & [::Send {Blind}{Up DownTemp}
Capslock & [ up::Send {Blind}{Up Up}
Capslock & '::Send {Blind}{Right DownTemp}
Capslock & ' up::Send {Blind}{Right Up}
; Capslock + uohy (pgdown, pgup, home, end)
Capslock & k::SendInput {Blind}{Home Down}
Capslock & k up::SendInput {Blind}{Home Up}
Capslock & ,::SendInput {Blind}{End Down}
Capslock & , up::SendInput {Blind}{End Up}
Capslock & l::SendInput {Blind}{PgUp Down}
Capslock & l up::SendInput {Blind}{PgUp Up}
Capslock & .::SendInput {Blind}{PgDn Down}
Capslock & . up::SendInput {Blind}{PgDn Up}
; Capslock + asdf (select all, cut-copy-paste)
Capslock & a::SendInput {Ctrl Down}{a Down}
Capslock & a up::SendInput {Ctrl Up}{a Up}
Capslock & s::SendInput {Ctrl Down}{x Down}
Capslock & s up::SendInput {Ctrl Up}{x Up}
Capslock & d::SendInput {Ctrl Down}{c Down}
Capslock & d up::SendInput {Ctrl Up}{c Up}
Capslock & f::SendInput {Ctrl Down}{v Down}
Capslock & f up::SendInput {Ctrl Up}{v Up}
; Capslock + wer (close tab or window, press esc)
Capslock & w::SendInput {Ctrl down}{F4}{Ctrl up}
Capslock & e::SendInput {Alt down}{F4}{Alt up}
Capslock & r::SendInput {Blind}{Esc Down}
; Capslock + nm (insert, backspace, del)
Capslock & \::SendInput {Blind}{Insert Down}
;Capslock & m::SendInput {Blind}{Del Down}
;Capslock & n::SendInput {Blind}{BS Down}
Capslock & BS::SendInput {Blind}{Del Down}
; Make Capslock & Enter equivalent to Control+Enter
Capslock & Enter::SendInput {Ctrl down}{Enter}{Ctrl up}
; Make Capslock & Alt Equivalent to Control+Alt
!Capslock::SendInput {Ctrl down}{Alt Down}
!Capslock up::SendInput {Ctrl up}{Alt up}
; Capslock + TAB/q (prev/next tab)
Capslock & q::SendInput {Ctrl Down}{Tab Down}
Capslock & q up::SendInput {Ctrl Up}{Tab Up}
Capslock & Tab::SendInput {Ctrl Down}{Shift Down}{Tab Down}
Capslock & Tab up::SendInput {Ctrl Up}{Shift Up}{Tab Up}
; Capslock + ,/. (undo/redo)
;Capslock & ,::SendInput {Ctrl Down}{z Down}
;Capslock & , up::SendInput {Ctrl Up}{z Up}
;Capslock & .::SendInput {Ctrl Down}{y Down}
;Capslock & . up::SendInput {Ctrl Up}{y Up}
; Make Capslock+Space -> Enter
Capslock & Space::SendInput {Enter Down}
; Make Win Key + Capslock work like Capslock
#Capslock::
If GetKeyState("CapsLock", "T") = 1
SetCapsLockState, AlwaysOff
Else
SetCapsLockState, AlwaysOn
Return
; Drag windows anywhere
;
; This script modified from the original: http://www.autohotkey.com/docs/scripts/EasyWindowDrag.htm
; by The How-To Geek
; http://www.howtogeek.com
Capslock & LButton::
CoordMode, Mouse ; Switch to screen/absolute coordinates.
MouseGetPos, EWD_MouseStartX, EWD_MouseStartY, EWD_MouseWin
WinGetPos, EWD_OriginalPosX, EWD_OriginalPosY,,, ahk_id %EWD_MouseWin%
WinGet, EWD_WinState, MinMax, ahk_id %EWD_MouseWin%
if EWD_WinState = 0 ; Only if the window isn't maximized
SetTimer, EWD_WatchMouse, 10 ; Track the mouse as the user drags it.
return
EWD_WatchMouse:
GetKeyState, EWD_LButtonState, LButton, P
if EWD_LButtonState = U ; Button has been released, so drag is complete.
{
SetTimer, EWD_WatchMouse, off
return
}
GetKeyState, EWD_EscapeState, Escape, P
if EWD_EscapeState = D ; Escape has been pressed, so drag is cancelled.
{
SetTimer, EWD_WatchMouse, off
WinMove, ahk_id %EWD_MouseWin%,, %EWD_OriginalPosX%, %EWD_OriginalPosY%
return
}
; Otherwise, reposition the window to match the change in mouse coordinates
; caused by the user having dragged the mouse:
CoordMode, Mouse
MouseGetPos, EWD_MouseX, EWD_MouseY
WinGetPos, EWD_WinX, EWD_WinY,,, ahk_id %EWD_MouseWin%
SetWinDelay, -1 ; Makes the below move faster/smoother.
WinMove, ahk_id %EWD_MouseWin%,, EWD_WinX + EWD_MouseX - EWD_MouseStartX, EWD_WinY + EWD_MouseY - EWD_MouseStartY
EWD_MouseStartX := EWD_MouseX ; Update for the next timer-call to this subroutine.
EWD_MouseStartY := EWD_MouseY
return
AutoHotKey - RealForce->HHKB 스타일 계속 업데이트 예정 | 
